* -------------- glb_2 standard closure file -----------------------------

$ontext
     glb_2_2_cl_std.inc

Description
 Full employment, balanced macro with flexible external balances
 All tax rates fixed, i.e., no tax replacement

                     CONDITION                                 REGIONS

     FEX        - Exchange rate fixed                            GLO
                - KAPWOR fixed                                   rgn

     Investment - savings rates are fixed                        All

     Government - taxes rates fixed                              All
                - absorption share fixed                         All
                - KAPGOV fixed                                   All

     Factors    - Land sector - mobile & full                    All
                - Capital - mobile & full                        All
                - Unskilled labour - mobile & full               All
                - Skilled labour - mobile & full                 All

     Numeraire  - CPI                                            All

$offtext

$ontext

*## FOREIGN EXCHANGE MARKET CLOSURE

 Fixed exchange rates for numeraire region
 External balances flexible for numeraire regions

 Flexible exchange rates for non numeraire regions
 External balances fixed for non numeraire regions

*## INVESTMENT-SAVINGS CLOSURE

 Investment share of final demand fixed
 Household savings rates fixed

*## GOVT CLOSURE RULES

 Fixed tax rates
 Internal balance flexible
 Govt share of final demand fixed

*## FACTOR MARKET CLOSURE

 Fully mobile
 Fully employed
 Technologies fixed

*## MISCELLANEOUS FIXED VARIABLES

 CPI region numeraires


$offtext
*## FOREIGN EXCHANGE MARKET CLOSURE

* fix world numeraire in which foreign transactions are valued

 ERPI.FX                 = ERPI0 * numerchk ;

* globe transactions are in the numeraire currency

 ER.FX("glo")            = ERPI0 * numerchk;

* the external balance is fixed for regions
* globes trade balance is zero by definition of tship and the fact that
* there is only one imported commodity

* In this MODEL the exchange rate for all regions EXCEPT GLO is fixed
* and the curent account balance is the equilibrating variable.

* ER.FX(rgn)                = ER0(rgn) ;

* alternatively the external balance is fixed for non-reference countries

 KAPWOR.FX(rgn)           = KAPWOR0(rgn) ;

*## INVESTMENT-SAVINGS CLOSURE
* IF aggregate investment is determined by aggregate savings
* i.e., the model is savings driven, then fix SADJ and DSHH
* Typically the actual/model savings rates are NOT fixed directly

* SADJ controls multiplictive changes in savings rates

 SADJ.FX(r)        = SADJ0(r) ;

* DSHH controls additive changes in savings rates
* NB DSHH needs to be used in conjunction with shh01

 DSHH.FX(r)         = DSHH0(r) ;

* ALTERNATIVELY the model is made investment driven
* If investment volume fixed then scaling factor is fixed

* IADJ.FX(r)         = IADJ0(r) ;

* OR if the value of investment is fixed the

* INVEST.FX(r)       = INVEST0(r) ;

* OR the shares of domestic final demand of investment is fixed

* INVESTSH.FX(r)     = INVESTSH0(r) ;

* Closure rule for Government savings is part of the Govt Closure Rules

*## GOVT CLOSURE RULES
* IF ALL tax rates are fixed
* AND Government consumption expenditure is fixed
* Then the equilibriating variable is Government Savings

* Tax rate scaling factors

* T*ADJ control multiplictive changes in tax rates

 TEADJ.FX(r)         = TEADJ0(r) ;
 TMADJ.FX(r)         = TMADJ0(r) ;
 TMSADJ.FX(r)        = TMSADJ0(r) ;
 TSADJ.FX(r)         = TSADJ0(r) ;
 TVADJ.FX(r)         = TVADJ0(r) ;
 TXADJ.FX(r)         = TXADJ0(r) ;
 TYFADJ.FX(r)        = TYFADJ0(r) ;
 TYHADJ.FX(r)        = TYHADJ0(r) ;
 TFADJ.FX(r)         = TFADJ0(r) ;

* Dt* control additive changes in tax rates
* NB DT* needs to be used in conjunction with t*01

 DTE.FX(r)           = DTE0(r) ;
 DTM.FX(r)           = DTM0(r) ;
 DTMS.FX(r)          = DTMS0(r) ;
 DTS.FX(r)           = DTS0(r) ;
 DTV.FX(r)           = DTV0(r) ;
 DTX.FX(r)           = DTX0(r) ;
 DTYF.FX(r)          = DTYF0(r) ;
 DTYH.FX(r)          = DTYH0(r) ;
 DTF.FX(r)           = DTF0(r) ;

* GOVERNMENT EXPENDITURE
* FIX volume

* QGDADJ.FX(r)        = QGDADJ0(r) ;

* OR FIX nominal

* EG.FX(r)           = EG0(r) ;

* OR FIX shares of final demand

* VGDSH.FX(r)         = VGDSH0(r) ;

* GOVERNMENT SAVINGS
* OR the internal balance / Govt savings can be fixed

 KAPGOV.FX(r)       = KAPGOV0(r) ;

*## FACTOR MARKET CLOSURE

*# Basic Factor Market Closure
*$ontext

 FS.FX(f,r)                = FS0(f,r) ;
 WFDIST.FX(f,a,r)          = WFDIST0(f,a,r) ;
 WF.LO(f,r)                = -inf ;
 WF.UP(f,r)                = +inf ;

* Unemployment
 WF.LO(f,r)$(NOT UEF(f,r))   = -inf ;
 WF.UP(f,r)$(NOT UEF(f,r))   = +inf ;
 WF.LO(f,r)$UEF(f,r)         = WF0(f,r) ;
 WF.UP(f,r)$UEF(f,r)         = + INF ;


*$offtext

* # Technology Closures for Factor Market

* NB SHIFT factors are fixed indirectly through the adjustment variables

* Technology for CES production functions for Level 1 of production nest

* To FIX ADX fix BOTH ADXADJ and DADX
* NB DADX needs to be used in conjunction with adx01

 ADXADJ.FX(r)        = ADXADJ0(r) ;
 DADX.FX(r)          = DADX0(r) ;

* Technology for CES aggregation functions for Level 2 of production nest

* To FIX ADVA fix BOTH ADVAADJ and DADVA
* NB DADVA needs to be used in conjunction with adva01

 ADVAADJ.FX(r)       = ADVAADJ0(r) ;
 DADVA.FX(r)         = DADVA0(r) ;

* Technology for factor activity and region specific factor efficiency

 ADFDfADJ.FX(f)      = ADFDfADJ0(f) ;
 ADFDaADJ.FX(a)      = ADFDaADJ0(a) ;
 ADFDrADJ.FX(r)      = ADFDrADJ0(r) ;

*## MISCELLANEOUS FIXED VARIABLES

* To use CPI as the numeraire fix CPI

 CPI.FX(r)            = CPI0(r)*numerchk ;

* To fix the real exchange rate fix ER and PPI

* PPI.FX(r)           = PPI0(r)*numerchk ;

* -------------- end of gl_s_cl_std basic closure ------------------------
